Podívejme se, jak to funguje

Máme k dispozici údaje z druhého národního průzkumu zdraví a výživy (NHANES II) (McDowell et al. 1981). Zajímá nás, jak se liší zdravotní ukazatele u diabetiků a nediabetiků. Začneme vytvořením „tabulky 1“:

V této tabulce jsou uvedeny průměrné hodnoty hmotnosti, systolického krevního tlaku, cholesterolu a triglyceridů pro každou skupinu. Provedli jsme také test rovnosti mezi diabetiky a nediabetiky pro tyto tři zdravotní ukazatele; tyto testy jsme potlačili pro věk, hmotnost a pohlaví. Pomocí jediného příkazu jsme schopni vytvořit a exportovat tuto tabulku do souboru kompatibilního s programem Word (table1.docx). Tuto tabulku však chceme zařadit do zprávy spolu s grafem, textem a dalším obsahem, což učiníme níže.

Začneme vytvořením aktivního dokumentu, přidáním názvu a úvodu naší analýzy:

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

Poté vložíme tabulku, kterou jsme vytvořili výše, i když tentokrát nebudeme potřebovat volbu export(). Místo toho použijeme putdocx style collect ke změně velikosti šířky sloupců tak, aby odpovídaly obsahu, a pomocí putdocx collect vložíme tabulku do našeho dokumentu.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

Dále se věnujeme výsledkům naší tabulky a odkazu na obrázek 1. Přestože jsme ještě nevytvořili záložku s názvem bmark1, naformátujeme text „obrázek 1“ jako odkaz na záložku.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

Nakonec vytvoříme sloupcový graf pro zobrazení průměrného systolického krevního tlaku pro každou věkovou skupinu a kategorii diabetu. Náš graf vyexportujeme do souboru SVG a přidáme k němu titulek. Název je „Obrázek 1. Systolický krevní tlak a diabetes“, který naformátujeme jako záložku. Poté vyexportujeme náš obrázek pomocí obrázku putdocx a zadáme alternativní text, který bude číst hlasový software. Nakonec naši práci uložíme.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Vytvoření souboru aplikace Excel se zamčenými buňkami

Máme data ze sčítání lidu z roku 1980, která chceme exportovat do souboru Excel. Zajímá nás, jak se liší počet obyvatel, počet zemřelých a sňatků v jednotlivých regionech Spojených států. Nejprve vypočítáme průměr pro počet obyvatel, počet úmrtí a počet sňatků. Poté vyexportujeme proměnné, které nás zajímají, do souboru s názvem report2.xlsx pomocí příkazu export excel. První řádek bude obsahovat názvy proměnných a první čtyři sloupce budou zaznamenávat region a průměry, které jsme vypočítali. Pro úpravu tohoto souboru použijeme sadu putexcel s volbou upravit. List rozdělíme na prvním řádku a čtvrtém sloupci pomocí volby split(1,4). Jinými slovy, tento řádek a sloupec uzamkneme, abychom měli průměry stále na očích, zatímco budeme procházet informace pro jednotlivé státy.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Zde je náš výsledný dokument:

Nyní se můžeme posouvat dolů do dalších oblastí, přičemž názvy sloupců zůstávají v zobrazení, a posouvat se doprava, přičemž průměry zůstávají v zobrazení:

Když se posuneme dolů do regionu Severní střední Evropy, zjistíme, že v průměru na jeden stát připadá 47 436 sňatků; nejvíce jich bylo uzavřeno v Illinois, a to 109 823.

Souhrnné statistiky pro jednotlivé regiony bychom také mohli ukládat do jednoho listu a na tabulku hypertextově odkazovat z jiného listu s novou podporou hypertextových odkazů. Pracovní list bychom mohli dále přizpůsobit tím, že bychom do něj vložili záhlaví, zápatí nebo zalomení stránky. Další informace naleznete v části [RPT] putexcel.

Materiály

Soubor do a výsledné dokumenty vytvořené ve výše uvedených příkladech si můžete stáhnout zadáním příkazu

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Odkaz

McDowell, A., A. Engel, J. T. Massey a K. Maurer. 1981. Plan and operation of the Second National Health and Nutrition Examination Survey, 1976-1980 (Plán a průběh druhého národního průzkumu zdraví a výživy, 1976-1980). Vital and Health Statistics 1: 1144.