Lássuk, hogyan működik

A második Nemzeti Egészség- és Táplálkozásvizsgálati Felmérésből (NHANES II) származó adatokkal rendelkezünk (McDowell et al. 1981). Az érdekel bennünket, hogy az egészségügyi mérések hogyan különböznek a cukorbetegek és a nem cukorbetegek között. Azzal kezdjük, hogy létrehozunk egy “1. táblázatot”:

Ebben a táblázatban az egyes csoportok átlagos testsúlya, szisztolés vérnyomása, koleszterinszintje és trigliceridszintje látható. A cukorbetegek és a nem cukorbetegek közötti egyenlőségi tesztet is elvégeztük a három egészségügyi mérőszám tekintetében; ezeket a teszteket az életkor, a testsúly és a nem tekintetében elnyomtuk. Egyetlen paranccsal létrehozhatjuk és exportálhatjuk ezt a táblázatot egy Word-kompatibilis fájlba (table1.docx). Ezt a táblázatot azonban egy grafikon, szöveg és egyéb tartalom mellett egy jelentésbe is be szeretnénk illeszteni, amit az alábbiakban meg is teszünk.

Először is létrehozunk egy aktív dokumentumot, hozzáadunk egy címet és egy bevezetőt az elemzésünkhöz:

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

Ezután beillesztjük a fent létrehozott táblázatot, bár ezúttal nem lesz szükségünk az export() opcióra. Ehelyett a collect style putdocx segítségével átméretezzük az oszlopszélességet a tartalomnak megfelelően, és a putdocx collect segítségével beillesztjük a táblázatot a dokumentumunkba.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

Ezután tárgyaljuk a táblázatunk eredményeit, és hivatkozunk az 1. ábrára. Bár még nem hoztuk létre a bmark1 nevű könyvjelzőt, a könyvjelzőre mutató hivatkozásként az “1. ábra” szöveget formázzuk.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

Végül egy oszlopdiagramot hozunk létre az átlagos szisztolés vérnyomás megjelenítésére minden egyes korcsoportra és diabéteszkategóriára vonatkozóan. Grafikonunkat SVG-fájlba exportáljuk, és címet adunk a képhez. A cím a következő: “1. ábra. Szisztolés vérnyomás és cukorbetegség”, amelyet könyvjelzőként formázunk. Ezután a putdocx image segítségével exportáljuk a képünket, és megadjuk az alternatív szöveget, amelyet a hangszoftverek felolvasnak. Végül elmentjük a munkánkat.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Zárolt cellákkal rendelkező Excel-fájl létrehozása

Az 1980-as népszámlálásból származó adatokkal rendelkezünk, amelyeket egy Excel-fájlba szeretnénk exportálni. Érdekel bennünket, hogy a népesség, a halálozások száma és a házasságkötések száma hogyan változik az Egyesült Államok egyes régióiban. Először is kiszámítjuk a népesség, a halálozások és a házasságkötések átlagát. Ezután az export excel programmal exportáljuk a minket érdeklő változókat egy report2.xlsx nevű fájlba. Az első sor tartalmazza a változók nevét, az első négy oszlop pedig az általunk kiszámított régiót és átlagokat rögzíti. Ennek a fájlnak a módosításához a putexcel set-et használjuk a modify opcióval. A munkalapot az első sorban és a negyedik oszlopban felosztjuk a split(1,4) opcióval. Más szóval, lezárjuk ezt a sort és oszlopot, hogy az átlagok láthatóak maradjanak, miközben az egyes államokra vonatkozó információkat görgetjük.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Íme az eredményül kapott dokumentum:

Most már lefelé görgethetünk más régiókhoz, miközben az oszlopnevek továbbra is láthatóak, és jobbra görgethetünk, miközben az átlagok továbbra is láthatóak:

Ha az észak-középső régióig görgetünk lefelé, azt látjuk, hogy átlagosan 47 436 házasságot kötöttek államonként; Illinois-ban volt a legtöbb, 109 823.

A hiperhivatkozások új támogatásával az egyes régiókra vonatkozó összefoglaló statisztikákat is tárolhatjuk egy munkalapon, és egy másik lapról hiperhivatkozhatunk a táblázatra. A munkalapot tovább testreszabhatjuk fejléccel, lábléccel vagy oldaltöréssel. További információkért lásd [RPT] putexcel.

Anyagok

A fenti példákban létrehozott do-file és az eredményül kapott dokumentumok letölthetők, ha beírja a következőt

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Hivatkozás

McDowell, A., A. Engel, J. T. Massey és K. Maurer. 1981. A második Nemzeti Egészség- és Táplálkozásvizsgálati Felmérés terve és működése, 1976-1980. Vital and Health Statistics 1: 1144.