Нека видим как работи

Разполагаме с данни от Второто национално изследване на здравето и храненето (NHANES II) (McDowell et al. 1981). Интересуваме се от това как се различават здравните показатели при диабетиците и недиабетиците. Започваме със създаването на „Таблица 1“:

В тази таблица са показани средното тегло, систоличното кръвно налягане, холестеролът и триглицеридите за всяка група. Извършихме и тест за равенство между диабетиците и недиабетиците за трите здравни показателя; потиснахме тези тестове за възраст, тегло и пол. С помощта на една команда сме в състояние да създадем и експортираме тази таблица в Word-съвместим файл (table1.docx). Искаме обаче да включим тази таблица в доклад заедно с графика, текст и друго съдържание, което ще направим по-долу.

Ще започнем със създаването на активен документ, като добавим заглавие и въведение към нашия анализ:

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

След това ще включим таблицата, която създадохме по-горе, макар че този път няма да се нуждаем от опцията export(). Вместо това ще използваме collect style putdocx, за да променим ширината на колоните, така че да пасне на съдържанието, и ще използваме putdocx collect, за да вмъкнем таблицата в нашия документ.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

Next, we discuss the results of our table and link to figure 1. Въпреки че все още не сме създали отметките, наречени bmark1, форматираме текста „фигура 1“ като връзка към отметките.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

Накрая създаваме стълбовидна графика, за да визуализираме средното систолично кръвно налягане за всяка възрастова група и категория диабет. Експортираме нашата графика в SVG файл и добавяме заглавие към изображението. Заглавието е „Фигура 1. Систолично кръвно налягане и диабет“, което оформяме като отметки. След това експортираме изображението си с помощта на putdocx image и посочваме алтернативен текст, който да бъде прочетен от гласов софтуер. Накрая запазваме работата си.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Създаване на файл на Excel със заключени клетки

Имаме данни от преброяването през 1980 г., които искаме да експортираме във файл на Excel. Интересува ни как населението, броят на смъртните случаи и браковете варират във всеки регион на САЩ. Първо, изчисляваме средната стойност за населението, смъртността и браковете. След това експортираме интересуващите ни променливи във файл, наречен report2.xlsx, с помощта на export excel. Първият ред ще съдържа имената на променливите, а в първите четири колони ще бъдат записани регионът и средните стойности, които сме изчислили. За да модифицираме този файл, използваме putexcel set с опцията modify. Разделяме работния лист на първия ред и четвъртата колона с опцията split(1,4). С други думи, заключваме този ред и колона, за да запазим средните стойности в полезрението, докато прелистваме информацията за всеки щат.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Ето какъв е резултатът от нашия документ:

Сега можем да превъртаме надолу към други региони, като запазваме изгледа на имената на колоните, и да превъртаме надясно, като запазваме изгледа на средните стойности:

Когато преминем към Северния централен регион, виждаме, че всеки щат е сключил средно по 47 436 брака; в Илинойс те са най-много – 109 823.

Можем също така да съхраняваме обобщени статистически данни за всеки регион в един работен лист и да правим хипервръзки към таблицата от друг лист с новата поддръжка на хипервръзки. Бихме могли да персонализираме работния си лист допълнително, като включим заглавие, колонтитул или прекъсване на страницата. Вижте [RPT] putexcel за повече информация.

Материали

Можете да изтеглите до-файла и получените документи, създадени в горните примери, като въведете

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Справка

McDowell, A., A. Engel, J. T. Massey, and K. Maurer. 1981. Plan and operation of the Second National Health and Nutrition Examination Survey, 1976-1980 (План и провеждане на Второто национално изследване на здравето и храненето, 1976-1980 г.). Vital and Health Statistics 1: 1144.