Давайте подивимося, як це працює

У нас є дані Другого національного дослідження здоров’я та харчування (NHANES II) (McDowell et al. 1981). Нас цікавить, наскільки показники здоров’я відрізняються між діабетиками та недіабетиками. Почнемо зі створення “Таблиці 1”:

У цій таблиці ми бачимо середню вагу, систолічний артеріальний тиск, рівень холестерину та тригліцеридів для кожної групи. Ми також провели тест на рівність між діабетиками та недіабетиками за трьома показниками здоров’я; ми придушили ці тести для віку, ваги та статі. За допомогою однієї команди ми можемо створити та експортувати цю таблицю у Word-сумісний файл (table1.docx). Однак ми хочемо включити цю таблицю до звіту разом з графіком, текстом та іншим вмістом, що ми і зробимо нижче.

Ми почнемо зі створення активного документа, додамо заголовок і вступ до нашого аналізу:

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

Потім ми додамо таблицю, яку ми створили вище, хоча цього разу нам не знадобиться опція export(). Замість цього ми використаємо стиль збору putdocx, щоб змінити ширину стовпців відповідно до вмісту, і використаємо putdocx collect, щоб вставити таблицю в наш документ.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

Далі ми обговорюємо результати нашої таблиці і робимо посилання на рисунок 1. Хоча ми ще не створили закладку з назвою bmark1, ми відформатуємо текст “figure 1” як посилання на закладку.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

Нарешті, ми створюємо гістограму для візуалізації середнього систолічного артеріального тиску для кожної вікової групи та категорії діабету. Ми експортуємо наш графік у файл SVG і додаємо до зображення заголовок. Назвемо його так: “Рисунок 1. Систолічний артеріальний тиск і діабет”, який ми форматуємо як закладку. Потім ми експортуємо наше зображення за допомогою putdocx image і вказуємо альтернативний текст, який буде прочитаний голосовим програмним забезпеченням. Нарешті, ми зберігаємо нашу роботу.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Створення файлу Excel із заблокованими клітинками

У нас є дані перепису населення 1980 року, які ми хочемо експортувати в файл Excel. Нас цікавить, як змінюється чисельність населення, кількість смертей та шлюбів у кожному регіоні США. Спочатку ми обчислюємо середнє значення для чисельності населення, кількості смертей і шлюбів. Потім ми експортуємо змінні, що нас цікавлять, у файл під назвою report2.xlsx за допомогою команди export excel. Перший рядок міститиме назви змінних, а перші чотири стовпчики – регіон і середні значення, які ми обчислили. Щоб змінити цей файл, ми використовуємо команду putexcel з опцією modify. Ми розділимо аркуш у першому рядку та четвертому стовпчику за допомогою опції split(1,4). Іншими словами, ми блокуємо цей рядок і стовпець, щоб бачити середні значення, поки ми прокручуємо інформацію для кожного стану.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Ось наш кінцевий документ:

Тепер ми можемо прокрутити вниз до інших регіонів, зберігаючи назви стовпців у полі зору, і прокрутити вправо, зберігаючи середні значення у полі зору:

Прокручуючи список до Північно-Центрального регіону, ми бачимо в середньому 47 436 шлюбів у кожному штаті; найбільше в Іллінойсі – 109 823.

Ми також можемо зберігати зведену статистику для кожного регіону на одному аркуші і посилатися на таблицю з іншого аркуша завдяки новій підтримці гіперпосилань. Ми можемо додатково налаштувати наш робочий аркуш, додавши верхній і нижній колонтитули або розрив сторінки. Дивіться [RPT] putexcel для отримання додаткової інформації.

Матеріали

Ви можете завантажити do-файл і результуючі документи, створені у наведених вище прикладах, набравши

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Посилання

Макдауелл, А., А. Енгель, Д. Т. Мессі та К. Маурер. 1981. План та проведення Другого національного обстеження стану здоров’я та харчування, 1976-1980. Статистика життєдіяльності та охорони здоров’я 1: 1144.