Să vedem cum funcționează

Dispunem de date din cel de-al doilea studiu național de examinare a sănătății și nutriției (NHANES II) (McDowell et al. 1981). Suntem interesați de modul în care diferă măsurile de sănătate între diabetici și non-diabetici. Începem prin a crea un „Tabel 1”:

În acest tabel, vedem greutatea medie, tensiunea arterială sistolică, colesterolul și trigliceridele pentru fiecare grup. Am efectuat, de asemenea, un test de egalitate între diabetici și non-diabetici pentru cele trei măsuri de sănătate; am suprimat aceste teste pentru vârstă, greutate și sex. Cu o singură comandă, suntem capabili să creăm și să exportăm acest tabel într-un fișier compatibil cu Word (table1.docx). Cu toate acestea, dorim să includem acest tabel într-un raport împreună cu un grafic, text și alt conținut, ceea ce facem mai jos.

Vom începe prin a crea un document activ, adăugând un titlu și o introducere la analiza noastră:

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

Apoi, vom include tabelul pe care l-am creat mai sus, deși de data aceasta nu vom avea nevoie de opțiunea export(). În schimb, vom folosi collect style putdocx pentru a redimensiona lățimea coloanelor pentru a se potrivi conținutului și vom folosi putdocx collect pentru a introduce tabelul în documentul nostru.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

În continuare, vom discuta rezultatele tabelului nostru și vom face legătura cu figura 1. Deși nu am creat încă semnul de carte numit bmark1, formatul textului „figura 1” este o legătură către semnul de carte.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

În cele din urmă, creăm un grafic cu bare pentru a vizualiza tensiunea arterială sistolică medie pentru fiecare grupă de vârstă și categorie de diabet. Exportăm graficul nostru într-un fișier SVG și adăugăm un titlu la imagine. Titlul este „Figura 1. Tensiunea arterială sistolică și diabetul”, pe care îl formatăm ca marcaj. Apoi exportăm imaginea noastră folosind imaginea putdocx și specificăm un text alternativ care să fie citit de software-ul vocal. În cele din urmă, ne salvăm munca.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Crearea unui fișier Excel cu celule blocate

Avem date de la recensământul din 1980 pe care dorim să le exportăm într-un fișier Excel. Suntem interesați de modul în care variază populația, numărul de decese și căsătoriile în fiecare regiune a Statelor Unite. În primul rând, calculăm media pentru populație, decese și căsătorii. Apoi, exportăm variabilele noastre de interes într-un fișier numit report2.xlsx cu export excel. Primul rând va conține numele variabilelor, iar primele patru coloane vor înregistra regiunea și mediile pe care le-am calculat. Pentru a modifica acest fișier, folosim setul putexcel cu opțiunea modify. Împărțim foaia de calcul la primul rând și la a patra coloană cu opțiunea split(1,4). Cu alte cuvinte, blocăm acest rând și această coloană pentru a păstra mediile la vedere, în timp ce parcurgem informațiile pentru fiecare stat.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Iată documentul rezultat:

Acum putem derula în jos spre alte regiuni, menținând în același timp numele coloanelor la vedere și putem derula spre dreapta, menținând în același timp mediile la vedere:

Dacă ne deplasăm în jos, în regiunea Nord-Centrală, observăm o medie de 47.436 de căsătorii pe stat; Illinois a avut cele mai multe, 109.823 de căsătorii.

Am putea, de asemenea, să stocăm statisticile sumare pentru fiecare regiune într-o foaie de lucru și să facem un hyperlink către tabel dintr-o altă foaie cu noul suport pentru hyperlink-uri. Am putea personaliza și mai mult foaia de lucru prin includerea unui antet, a unui picior de pagină sau a unei pauze de pagină. Pentru mai multe informații, consultați [RPT] putexcel.

Materiale

Puteți descărca fișierul de lucru și documentele rezultate create în exemplele de mai sus, tastând

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Referință

McDowell, A., A. Engel, J. T. Massey și K. Maurer. 1981. Planul și funcționarea celui de-al doilea studiu național de examinare a sănătății și nutriției, 1976-1980. Statistici vitale și de sănătate 1: 1144.