Voyons comment cela fonctionne

Nous disposons de données provenant de la deuxième enquête nationale sur la santé et la nutrition (NHANES II) (McDowell et al. 1981). Nous nous intéressons à la manière dont les mesures de santé diffèrent entre les diabétiques et les non-diabétiques. Nous commençons par créer un « tableau 1 » :

Dans ce tableau, nous voyons le poids moyen, la tension artérielle systolique, le cholestérol et les triglycérides pour chaque groupe. Nous avons également effectué un test d’égalité entre diabétiques et non-diabétiques pour les trois mesures de santé ; nous avons supprimé ces tests pour l’âge, le poids et le sexe. Une seule commande nous permet de créer et d’exporter ce tableau dans un fichier compatible avec Word (table1.docx). Cependant, nous souhaitons inclure ce tableau dans un rapport avec un graphique, du texte et d’autres contenus, ce que nous faisons ci-dessous.

Nous commencerons par créer un document actif, en ajoutant un titre et une introduction à notre analyse :

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

Ensuite, nous inclurons le tableau que nous avons créé ci-dessus, bien que cette fois-ci nous n’aurons pas besoin de l’option export(). Au lieu de cela, nous utilisons putdocx collect style pour redimensionner la largeur des colonnes afin d’adapter le contenu et nous utilisons putdocx collect pour insérer le tableau dans notre document.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

Ensuite, nous discutons des résultats de notre tableau et nous établissons un lien avec la figure 1. Bien que nous n’ayons pas encore créé le signet appelé bmark1, nous formatons le texte « figure 1 » comme un lien vers le signet.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

Enfin, nous créons un graphique à barres pour visualiser la pression artérielle systolique moyenne pour chaque groupe d’âge et chaque catégorie de diabète. Nous exportons notre graphique vers un fichier SVG et ajoutons un titre à l’image. Le titre est « Figure 1. Pression artérielle systolique et diabète », que nous formatons comme un signet. Nous exportons ensuite notre image à l’aide de putdocx image et spécifions un texte alternatif qui sera lu par un logiciel vocal. Enfin, nous sauvegardons notre travail.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Création d’un fichier Excel avec des cellules verrouillées

Nous disposons de données issues du recensement de 1980 que nous souhaitons exporter dans un fichier Excel. Nous souhaitons savoir comment la population, le nombre de décès et les mariages varient d’une région à l’autre des États-Unis. Tout d’abord, nous calculons la moyenne de la population, des décès et des mariages. Nous exportons ensuite nos variables d’intérêt vers un fichier appelé report2.xlsx avec export excel. La première ligne contient les noms des variables et les quatre premières colonnes indiquent la région et les moyennes que nous avons calculées. Pour modifier ce fichier, nous utilisons putexcel avec l’option modifier. Nous divisons la feuille de calcul au niveau de la première ligne et de la quatrième colonne avec l’option split(1,4). En d’autres termes, nous verrouillons cette ligne et cette colonne pour que les moyennes restent visibles pendant que nous faisons défiler les informations pour chaque État.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Voici le document qui en résulte :

Nous pouvons maintenant faire défiler les régions vers le bas tout en conservant les noms des colonnes et vers la droite tout en conservant les moyennes :

En descendant jusqu’à la région Centre-Nord, nous constatons une moyenne de 47 436 mariages par État ; c’est l’Illinois qui en compte le plus, avec 109 823.

Nous pourrions également stocker des statistiques sommaires pour chaque région dans une feuille de calcul et créer un lien hypertexte vers le tableau à partir d’une autre feuille grâce à la nouvelle prise en charge des liens hypertextes. Nous pourrions personnaliser davantage notre feuille de calcul en y ajoutant un en-tête, un pied de page ou un saut de page. Voir [RPT] putexcel pour plus d’informations.

Matériaux

Vous pouvez télécharger le fichier do et les documents créés dans les exemples ci-dessus en tapant

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Référence

McDowell, A., A. Engel, J. T. Massey, et K. Maurer. 1981. Plan et fonctionnement de la deuxième enquête nationale sur la santé et la nutrition, 1976-1980. Vital and Health Statistics 1 : 1144.