Wir wollen sehen, wie es funktioniert

Uns liegen Daten aus der zweiten nationalen Gesundheits- und Ernährungserhebung (NHANES II) vor (McDowell et al. 1981). Uns interessiert, wie sich die Gesundheitsmaße zwischen Diabetikern und Nichtdiabetikern unterscheiden. Wir beginnen mit der Erstellung einer „Tabelle 1“:

In dieser Tabelle sind das Durchschnittsgewicht, der systolische Blutdruck, das Cholesterin und die Triglyceride für jede Gruppe angegeben. Wir haben auch einen Test auf Gleichheit zwischen Diabetikern und Nicht-Diabetikern für die drei Gesundheitsmaße durchgeführt; wir haben diese Tests für Alter, Gewicht und Geschlecht unterdrückt. Mit einem einzigen Befehl können wir diese Tabelle erstellen und in eine Word-kompatible Datei (table1.docx) exportieren. Wir möchten diese Tabelle jedoch zusammen mit einem Diagramm, Text und anderen Inhalten in einen Bericht einfügen, was wir im Folgenden tun.

Wir beginnen mit der Erstellung eines aktiven Dokuments, fügen einen Titel und eine Einleitung zu unserer Analyse hinzu:

putdocx begin
putdocx textblock begin, style(Title)
Health report
putdocx textblock end
putdocx textblock begin
Below, we load data from the Second National Health and Nutrition
Examination Survey (NHANES II) (McDowell et al. 1981). We are interested in
how health measures differ across diabetics and non-diabetics.
putdocx textblock end

Dann fügen wir die Tabelle ein, die wir oben erstellt haben, obwohl wir dieses Mal die Option export() nicht brauchen werden. Stattdessen verwenden wir collect style putdocx, um die Spaltenbreiten an den Inhalt anzupassen, und verwenden putdocx collect, um die Tabelle in unser Dokument einzufügen.

. quietly: dtable age weight bpsystol tcresult tgresult i.sex, by(diabetes, tests)
   title(Table 1) continuous(age weight, test(none)) factor(sex, test(none))
   nformat(%6.1f mean sd)

. collect style putdocx, layout(autofitcontents)

. putdocx collect
(collection DTable posted to putdocx)

Als nächstes besprechen wir die Ergebnisse unserer Tabelle und verlinken auf Abbildung 1. Obwohl wir das Lesezeichen namens bmark1 noch nicht erstellt haben, formatieren wir den Text „Abbildung 1“ als Link zum Lesezeichen.

putdocx textblock begin
In this table, we find strong evidence that the mean systolic blood pressure,
cholesterol, and triglycerides differ across diabetics and non-diabetics. We
visualize how systolic blood pressure changes with age group in
<<dd_docx_display bookmarklink("bmark1"): "figure 1">>. We see that systolic
blood pressure climbs with age, and for individuals in their 30s and older,
those with diabetes have higher blood pressure than those without, on
average.
putdocx textblock end

Schließlich erstellen wir ein Balkendiagramm, um den durchschnittlichen systolischen Blutdruck für jede Altersgruppe und Diabeteskategorie darzustellen. Wir exportieren unser Diagramm in eine SVG-Datei und fügen dem Bild einen Titel hinzu. Der Titel lautet „Abbildung 1. Systolischer Blutdruck und Diabetes“, den wir als Lesezeichen formatieren. Dann exportieren wir unser Bild mit putdocx image und geben einen alternativen Text an, der von einer Sprachsoftware gelesen werden kann. Zuletzt speichern wir unsere Arbeit.

. graph bar (mean) bpsystol, over(agegrp) over(diabetes)
   asyvars blabel(bar, format(%6.1f)) ytitle(Mean systolic blood pressure)

. graph export graph1.svg, replace
file graph1.svg saved as SVG format

. putdocx paragraph, halign(center)

. putdocx text ("Figure 1. Systolic blood pressure and diabetes"),
    bookmark("bmark1")

. putdocx image graph1.svg, linebreak
    alt("Graph of systolic blood pressure and diabetes")

. putdocx save report1, replace
successfully replaced "C:/Users/Stata/report1.docx"

Erstellen einer Excel-Datei mit gesperrten Zellen

Wir haben Daten aus der Volkszählung von 1980, die wir in eine Excel-Datei exportieren möchten. Uns interessiert, wie sich die Bevölkerung, die Zahl der Sterbefälle und die Eheschließungen in den einzelnen Regionen der Vereinigten Staaten unterscheiden. Zunächst berechnen wir den Mittelwert für Bevölkerung, Sterbefälle und Eheschließungen. Anschließend exportieren wir unsere interessierenden Variablen in eine Datei namens report2.xlsx mit export excel. Die erste Zeile enthält die Namen der Variablen, und die ersten vier Spalten enthalten die Region und die berechneten Mittelwerte. Um diese Datei zu ändern, verwenden wir putexcel mit der Option modify. Wir teilen das Arbeitsblatt in der ersten Zeile und der vierten Spalte mit der Option split(1,4). Mit anderen Worten, wir sperren diese Zeile und Spalte, um die Durchschnittswerte im Blick zu behalten, während wir durch die Informationen für jedes Bundesland blättern.

. webuse census, clear
(1980 Census data by state)

. foreach x of varlist pop death marriage {
  2.     bysort region: egen avg_`x' = mean(`x')
  3. }

. export excel region avg_* pop de marriage state using report2.xlsx,
    firstrow(variables) replace 
file report2.xlsx saved

. putexcel set report2.xlsx, modify 

. putexcel sheetset, split(1, 4) 
file report2.xlsx saved

. putexcel save

Hier ist unser Ergebnisdokument:

Wir können nun nach unten zu anderen Regionen blättern und dabei die Spaltennamen im Blick behalten und nach rechts blättern und dabei die Durchschnittswerte im Blick behalten:

Wenn wir zur Region North Central hinunterblättern, sehen wir einen Durchschnitt von 47.436 Eheschließungen pro Staat; Illinois hatte mit 109.823 die meisten.

Wir könnten auch zusammenfassende Statistiken für jede Region in einem Arbeitsblatt speichern und mit Hilfe der neuen Unterstützung für Hyperlinks von einem anderen Blatt aus auf die Tabelle verweisen. Wir könnten unser Arbeitsblatt weiter anpassen, indem wir eine Kopf- oder Fußzeile oder einen Seitenumbruch einfügen. Siehe [RPT] putexcel für weitere Informationen.

Werkstoffe

Sie können die in den obigen Beispielen erstellte Do-Datei und die daraus resultierenden Dokumente herunterladen, indem Sie Folgendes eingeben

. copy https://www.stata.com/stata18/reporting-features-do 

. copy https://www.stata.com/stata18/reporting-features-report1.docx

. copy https://www.stata.com/stata18/reporting-features-report2.xlsx

Referenz

McDowell, A., A. Engel, J. T. Massey, und K. Maurer. 1981. Plan und Durchführung der zweiten nationalen Gesundheits- und Ernährungserhebung, 1976-1980. Vital- und Gesundheitsstatistiken 1: 1144.