Protože je dtable postaven na sadě příkazů collect, která je určena pro přizpůsobení jakéhokoli typu tabulky, můžete pomocí příkazů collect dále přizpůsobovat vzhled svých tabulek i po jejich vytvoření pomocí dtable.

Podívejme se, jak to funguje

-> Jednoduchý příklad
-> Definování vlastních statistik
-> Další přizpůsobení pomocí collect

Příklad sbírky

Pro začátek načteme data z druhého národního průzkumu zdraví a výživy (NHANES II) (McDowell et al. 1981). Chceme souhrnné statistiky pro uvedené proměnné, ale zvlášť pro každou kategorii diabetu. Všimněte si, že používáme faktorovou notaci proměnných, abychom naznačili, že pohlaví a rasa jsou kategoriální proměnné. A tabulku exportujeme do souboru table1.html:

. webuse nhanes2l, clear
(Second National Health and Nutrition Examination Survey)

. dtable age weight bpsystol i.sex i.race, by(diabetes) export(table1.html, replace)

(collection DTable exported to file table1.html)

Takto snadno lze vytvořit a exportovat tabulku. Pokud dáváte přednost exportu této tabulky do jiného formátu, například LaTeX nebo PDF, stačí zadat příslušnou příponu souboru. Ačkoli se jedná o informativní tabulku, níže si ji dále přizpůsobíme.

Ve výchozím nastavení dtable uvádí průměry a směrodatné odchylky pro spojité proměnné a počty a procenta pro faktorové proměnné. Vidíme, že zhruba 95 % našeho vzorku není diabetiků, zatímco 5 % ano. Vidíme také, že průměrný systolický krevní tlak pro skupinu nediabetiků je 130 a průměr pro skupinu diabetiků je 147. Můžeme testovat, zda se průměrný systolický krevní tlak liší v závislosti na stavu diabetiků. Můžeme také otestovat, zda jsou pohlaví a stav diabetika nezávislé. Mohli bychom uvést testy porovnávající všechny proměnné napříč skupinami se statusem diabetika. Nás však nezajímá porovnání věkového nebo rasového složení obou skupin, proto tyto testy pro věk a rasu potlačíme. Potlačujeme také popisné statistiky pro celkový vzorek, sloupec označený „Celkem“:

. dtable age weight bpsystol i.sex i.race, by(diabetes, nototals tests)
continuous(age, test(none)) factor(race, test(none))
note: using test regress across levels of diabetes for weight and bpsystol.
note: using test pearson across levels of diabetes for sex.

    Dále zadáme podvolbu place(seplabels), která umístí frekvenci pro každý podvzorek do popisku sloupce, ale na samostatný řádek. Ve výchozím nastavení se pro každou skupinu uvádějí četnosti i procenta, ale my chceme pouze četnosti. Dále můžeme upravit způsob zobrazení našich statistik pomocí volby sformat(); zde uzavíráme počty do závorek. Přidáme také poznámku s celkovou velikostí vzorku a ze záhlaví sloupce skryjeme popisek proměnné by().    

. dtable age weight bpsystol i.sex i.race, by(diabetes, nototals tests)
continuous(age, test(none)) factor(race, test(none))
sample(, statistics(freq) place(seplabels)) sformat("(N=%s)" frequency)
note(Total sample: N = 10,349)  column(by(hide))
note: using test regress across levels of diabetes for weight and bpsystol.
note: using test pearson across levels of diabetes for sex.

Total sample: N = 10,349

Nakonec zformátujeme průměry a směrodatné odchylky na dvě desetinná místa, přidáme nadpis a výslednou tabulku exportujeme do souboru HTML:

. dtable age weight bpsystol i.sex i.race, by(diabetes, nototals tests)
continuous(age, test(none)) factor(race, test(none))
sample(, statistics(freq) place(seplabels)) sformat("(N=%s)" frequency)
note(Total sample: N = 10,349) column(by(hide))
nformat(%7.2f mean sd) title(Table 1. Demographics) export(table1.html, replace)
note: using test regress across levels of diabetes for weight and bpsystol.
note: using test pearson across levels of diabetes for sex.

Table 1. Demographics

Total sample: N = 10,349
(collection DTable exported to file table1.html)

Definování vlastních statistik

dtable nabízí širokou škálu statistik, které můžete do tabulky zahrnout, například variační koeficient, geometrický průměr, šikmost a mnoho dalších. Možná však budete chtít kombinovat statistiky v jedné buňce. Například mezikvartilové rozpětí můžete umístit hned vedle mediánu. Pomocí dtable můžete vytvořit složené výsledky z libovolné z podporovaných statistik.

Níže chceme porovnat některá měření týkající se zdraví u osob, které prodělaly infarkt, s těmi, které ho neprodělaly. Chceme mít v jedné buňce průměry a směrodatné odchylky oddělené znaménkem plus minus. Kromě toho chceme, aby mezikvartilové rozpětí bylo umístěno hned vedle mediánu. Definujeme každý z těchto složených výsledků a určíme oddělovač. Poté zadáme statistiky, které chceme pro každou proměnnou. Přidáme také volbu svy, aby se statistiky počítaly pomocí vah průzkumu.

. dtable, by(heartatk, tests) svy
        define(meansd = mean sd, delimiter(" ± "))
        define(myiqr = p25 p75, delimiter("-"))
        continuous(age, stat(meansd) test(none))
        continuous(bmi, stat(meansd))
        continuous(bpsystol tcresult, stat(median myiqr))
note: using test regress across levels of heartatk for bmi, bpsystol, and tcresult.

Dále zformátujeme percentily a mediány na nula desetinných míst a mezikvartilové rozpětí uvedeme v závorce. Standardně jsou směrodatné odchylky umístěny v závorkách, ale níže závorky odstraníme:

. dtable, by(heartatk, tests) svy
        define(meansd = mean sd, delimiter(" ± "))
        define(myiqr = p25 p75, delimiter("-"))
        continuous(age, stat(meansd) test(none))
        continuous(bmi, stat(meansd))
        continuous(bpsystol tcresult, stat(median myiqr))
        nformat(%6.0f p25 p75 median) sformat("(%s)" myiqr)
        nformat(%6.1f mean sd) sformat("%s" sd)
note: using test regress across levels of heartatk for bmi, bpsystol, and tcresult.

Nakonec odstraníme popisek proměnné by(), změníme popisek sloupce „Celkem“ a změníme popisek p-hodnot:

. dtable, by(heartatk, tests) svy
        define(meansd = mean sd, delimiter(" ± "))
        define(myiqr = p25 p75, delimiter("-"))
        continuous(age, stat(meansd) test(none))
        continuous(bmi, stat(meansd))
        continuous(bpsystol tcresult, stat(median myiqr))
        nformat(%6.0f p25 p75 median) sformat("(%s)" myiqr)
        nformat(%6.1f mean sd) sformat("%s" sd)
        column(by(hide) total(All) test(P-value))
note: using test regress across levels of heartatk for bmi, bpsystol, and tcresult.

Další přizpůsobení pomocí collect

Zatímco dtable je navržen tak, aby vytvořil a exportoval tabulku v jednom kroku, můžete tyto tabulky dále upravovat pomocí sady příkazů collect. Níže změníme barvu okrajů a barvu pozadí pro střídající se řádky v naší tabulce:

. collect style cell border_block[column-header corner],
border(top, color(cyan))
. * Change the border color above the corner and column headers to cyan

. collect style cell border_block[row-header item],
border(bottom, color(cyan))
border(top, color(cyan))
. * Change the border color above and below the results and row headers to cyan

. collect style cell cell_type[column-header], font(, bold)
. * Make the column headers bold

. collect style cell var[_N bmi tcresult], shading(background(cyan))
. /*
Change the background color to cyan for the rows corresponding to N,
BMI, and cholesterol
*/

Nakonec určíme, že šířka sloupců má být změněna tak, aby odpovídala obsahu tabulky, a tabulku exportujeme:

. collect style putdocx, layout(autofitcontents)

. collect export table2.docx, replace
(collection DTable exported to file table2.docx)

Here is our resulting document:

Odkaz

McDowell, A., A. Engel, J. T. Massey a K. Maurer. 1981. Plan and operation of the Second National Health and Nutrition Examination Survey, 1976-1980 (Plán a průběh druhého národního průzkumu zdraví a výživy v letech 1976-1980). Vital and Health Statistics 1: 1144.