Освен това, тъй като dtable е изградена на базата на набора от команди collect, който е предназначен за персонализиране на всякакъв тип таблици, можете да използвате командите collect, за да персонализирате допълнително външния вид на вашите таблици, след като сте ги създали с помощта на dtable.

Нека видим как работи

-> Прост пример
-> Определяне на собствена статистика
-> Допълнително персонализиране с помощта на collect

Пример за събиране

За да започнем, зареждаме данни от Второто национално изследване на здравето и храненето (NHANES II) (McDowell et al. 1981). Искаме обобщена статистика за посочените променливи, но поотделно за всяка категория диабет. Обърнете внимание, че използваме запис на факторни променливи, за да посочим, че полът и расата са категорични променливи. И експортираме таблицата във файла table1.html:

. webuse nhanes2l, clear
(Second National Health and Nutrition Examination Survey)

. dtable age weight bpsystol i.sex i.race, by(diabetes) export(table1.html, replace)

(collection DTable exported to file table1.html)

Ето колко лесно може да се създаде и експортира таблица. Ако предпочитате да експортирате тази таблица в друг формат, например LaTeX или PDF, просто посочете съответното разширение на файла. Въпреки че това е информационна таблица, по-долу ще я персонализираме допълнително.

По подразбиране dtable отчита средни стойности и стандартни отклонения за непрекъснати променливи и брой и проценти за факторни променливи. Можем да видим, че приблизително 95% от нашата извадка не е диабетична, а 5% е. Виждаме също, че средното систолично кръвно налягане за групата на недиабетиците е 130, а средното за групата на диабетиците е 147. Можем да проверим дали средното систолично кръвно налягане се различава в зависимост от диабетния статус. Можем също така да проверим дали полът и диабетният статус са независими. Можем да отчетем тестове, сравняващи всички променливи в групите с диабетен статус. Ние обаче не се интересуваме от сравняване на възрастовия или расовия състав на двете групи, затова потискаме тези тестове за възраст и раса. Потискаме и описателната статистика за цялата извадка, колоната, обозначена като „Общо“:

. dtable age weight bpsystol i.sex i.race, by(diabetes, nototals tests)
continuous(age, test(none)) factor(race, test(none))
note: using test regress across levels of diabetes for weight and bpsystol.
note: using test pearson across levels of diabetes for sex.

    След това посочваме подварианта place(seplabels), за да поставим честотата за всяка подпроба в етикета на колоната, но на отделен ред. По подразбиране за всяка група се съобщават както честотите, така и процентите, но ние искаме да получим само честотите. Освен това можем да променим начина, по който се показват нашите статистически данни, като използваме опцията sformat(); тук поставяме броячите в скоби. Ще добавим и бележка с общия размер на извадката и ще скрием етикета за променливата by() от заглавието на колоната.    

. dtable age weight bpsystol i.sex i.race, by(diabetes, nototals tests)
continuous(age, test(none)) factor(race, test(none))
sample(, statistics(freq) place(seplabels)) sformat("(N=%s)" frequency)
note(Total sample: N = 10,349)  column(by(hide))
note: using test regress across levels of diabetes for weight and bpsystol.
note: using test pearson across levels of diabetes for sex.

Total sample: N = 10,349

Накрая форматираме средните стойности и стандартните отклонения до два знака след десетичната запетая, добавяме заглавие и експортираме крайната таблица в HTML файл:

. dtable age weight bpsystol i.sex i.race, by(diabetes, nototals tests)
continuous(age, test(none)) factor(race, test(none))
sample(, statistics(freq) place(seplabels)) sformat("(N=%s)" frequency)
note(Total sample: N = 10,349) column(by(hide))
nformat(%7.2f mean sd) title(Table 1. Demographics) export(table1.html, replace)
note: using test regress across levels of diabetes for weight and bpsystol.
note: using test pearson across levels of diabetes for sex.

Table 1. Demographics

Total sample: N = 10,349
(collection DTable exported to file table1.html)

Определяне на собствена статистика

dtable предлага широк набор от статистически данни, които можете да включите в таблицата си, като например коефициент на вариация, средна геометрична стойност, изкривяване и много други. Може обаче да искате да комбинирате статистики в една клетка. Например може да поставите интерквартилния диапазон точно до медианата. С dtable можете да създавате съставни резултати от всяка от поддържаните статистики.

По-долу искаме да сравним някои показатели, свързани със здравето, на лица, които са претърпели инфаркт, с тези, които не са. Искаме средни стойности и стандартни отклонения в една клетка, разделени със знака плюс минус. Освен това искаме междукварталния диапазон да бъде поставен точно до медианата. Определяме всеки от тези съставни резултати и посочваме разделителя. След това посочваме статистическите данни, които искаме за всяка променлива. Също така добавяме опцията svy, така че статистиките да бъдат изчислени, като се използват теглата на изследването.

. dtable, by(heartatk, tests) svy
        define(meansd = mean sd, delimiter(" ± "))
        define(myiqr = p25 p75, delimiter("-"))
        continuous(age, stat(meansd) test(none))
        continuous(bmi, stat(meansd))
        continuous(bpsystol tcresult, stat(median myiqr))
note: using test regress across levels of heartatk for bmi, bpsystol, and tcresult.

След това ще форматираме персентилите и медианите до нула знака след десетичната запетая, а междукварталния диапазон ще поставим в скоби. По подразбиране стандартните отклонения се поставят в скоби, но по-долу ще премахнем скобите:

. dtable, by(heartatk, tests) svy
        define(meansd = mean sd, delimiter(" ± "))
        define(myiqr = p25 p75, delimiter("-"))
        continuous(age, stat(meansd) test(none))
        continuous(bmi, stat(meansd))
        continuous(bpsystol tcresult, stat(median myiqr))
        nformat(%6.0f p25 p75 median) sformat("(%s)" myiqr)
        nformat(%6.1f mean sd) sformat("%s" sd)
note: using test regress across levels of heartatk for bmi, bpsystol, and tcresult.

Накрая премахваме етикета на променливата by(), променяме етикета на колоната „Общо“ и променяме етикета на p-стойностите:

. dtable, by(heartatk, tests) svy
        define(meansd = mean sd, delimiter(" ± "))
        define(myiqr = p25 p75, delimiter("-"))
        continuous(age, stat(meansd) test(none))
        continuous(bmi, stat(meansd))
        continuous(bpsystol tcresult, stat(median myiqr))
        nformat(%6.0f p25 p75 median) sformat("(%s)" myiqr)
        nformat(%6.1f mean sd) sformat("%s" sd)
        column(by(hide) total(All) test(P-value))
note: using test regress across levels of heartatk for bmi, bpsystol, and tcresult.

Допълнително персонализиране с помощта на collect

Въпреки че dtable е проектиран да създава и експортира таблица в една стъпка, можете да персонализирате тези таблици допълнително с набора от команди collect. По-долу променяме цвета на границите и цвета на фона за редуващите се редове в нашата таблица:

. collect style cell border_block[column-header corner],
border(top, color(cyan))
. * Change the border color above the corner and column headers to cyan

. collect style cell border_block[row-header item],
border(bottom, color(cyan))
border(top, color(cyan))
. * Change the border color above and below the results and row headers to cyan

. collect style cell cell_type[column-header], font(, bold)
. * Make the column headers bold

. collect style cell var[_N bmi tcresult], shading(background(cyan))
. /*
Change the background color to cyan for the rows corresponding to N,
BMI, and cholesterol
*/

Накрая указваме ширината на колоните да бъде променена така, че да отговаря на съдържанието на таблицата, и експортираме таблицата:

. collect style putdocx, layout(autofitcontents)

. collect export table2.docx, replace
(collection DTable exported to file table2.docx)

Here is our resulting document:

Справка

McDowell, A., A. Engel, J. T. Massey и K. Maurer. 1981. Plan and operation of the Second National Health and Nutrition Examination Survey, 1976-1980 (План и провеждане на Второто национално изследване на здравето и храненето, 1976-1980 г.). Vital and Health Statistics 1: 1144.